如何在julia中的元组中平铺命名的元组？

debugcn 发表于 Dev

米哈姓

我有一个Tuple元素，其中一些是NamedTuple。我想像这样将NamedTuples展平：

julia> nt = (a="a", b="b")
(a = "a", b = "b")

julia> t = (1, 2, 3, nt)
(1, 2, 3, (a = "a", b = "b"))

julia> res = tuple(1, 2, 3, nt...)
(1, 2, 3, "a", "b")

如何以编程方式执行此操作？我尝试了以下方法：

julia> exprs = [x isa NamedTuple ? Meta.parse("$x...") : x for x in t]
4-element Array{Any,1}:
 1                        
 2                        
 3                        
  :((a = "a", b = "b")...)

julia> res = tuple(eval(ex) for ex in exprs)
(Base.Generator{Array{Any,1},typeof(eval)}(Base.MainInclude.eval, Any[1, 2, 3, :((a = "a", b = "b")...)]),)

但这并不能完全满足我的要求： (1, 2, 3, "a", "b")

BogumiłKamiński

最简单的方法是编写：

julia> Tuple(Iterators.flatten((1,2,3, (a="a",b="b"))))
(1, 2, 3, "a", "b")

这样做的缺点是类型不稳定，并且将使所有可迭代对象（不仅NamedTuple是s）变平。

如果只想展NamedTuple平，则可以使用如下所示的方法：

julia> Tuple(reduce((a,b) -> (b isa NamedTuple ? append! : push!)(a, b), (1,2,3, (a="a",b="b")), init=[]))
(1, 2, 3, "a", "b")

（仍然会不稳定）

如果您想要稳定的类型，则可以使用递归，例如：

flatten() = ()
flatten(a::NamedTuple) = Tuple(a)
flatten(a) = (a,)
flatten(a::NamedTuple, b...) = tuple(a..., flatten(b...)...)
flatten(a, b...) = tuple(a, flatten(b...)...)
flatten_tuple(x::Tuple) = flatten(x...)

现在您有：

julia> flatten_tuple((1,2,3, (a="a",b="b")))
(1, 2, 3, "a", "b")

julia> @code_warntype flatten_tuple((1,2,3, (a="a",b="b")))
Variables
  #self#::Core.Compiler.Const(flatten_tuple, false)
  x::Tuple{Int64,Int64,Int64,NamedTuple{(:a, :b),Tuple{String,String}}}

Body::Tuple{Int64,Int64,Int64,String,String}
1 ─ %1 = Core._apply_iterate(Base.iterate, Main.flatten, x)::Tuple{Int64,Int64,Int64,String,String}
└──      return %1

本文收集自互联网，转载请注明来源。

如有侵权，请联系[email protected] 删除。