我想在子程序中分配一个数组，然后在主程序中使用该数组并将其传递给其他子程序。过去（F77？）传递可以在一个通用块中完成，但如今，最受欢迎的过程似乎是使用模块。当我尝试执行此操作时，如代码示例中所示，编译器告诉我
Rank mismatch in argument ‘f’ at (1) (scalar and rank-1)
显然，主程序认为'f'是一个标量：但是，我读这段代码意味着我已经在子例程内部和主程序中将其声明为一维数组。我想念什么？
我已经尝试了各种变体，例如将变量声明为模块的一部分，但是我想到的一切都没有使编译无错误（并且有些产生了更多的错误；-(）。对任何见解都表示赞赏。
module subs
contains
subroutine makef(f)
end subroutine makef
end module subs
c-----------------------------------------------------------------------
program work
use subs
implicit none
real, allocatable :: f(:)
call makef(f)
write (*,*) f
stop
end
c---------------------------------------------------------------------
subroutine makef(f)
implicit none
real, allocatable, intent(out) :: f(:)
integer :: i
integer :: is
is=10
allocate(f(-is:is))
do i=-is,is
f(i)=i
end do
return
end subroutine makef
Fortran中的模块与其他语言中的头文件不同，后者仅提供有关在其他地方定义的内容的信息。存在“延迟定义”（子模块）的概念，但是在这种情况下，模块应说明有关子例程的所有内容，而不仅仅是尝试指出其存在。
在问题的示例中，我们有：主程序；一个模块subs与模块过程makef; 外部子程序makef。
主程序使用模块subs及其程序makef，因此在主程序中引用的makef是该模块程序而不是外部子程序makef。
模块子例程makef具有f不带声明语句的参数，从而使其成为隐式声明的标量/外部函数。这是编译器的消息。implicit none在模块中使用，就像在主程序和外部子例程中一样。
子例程的整个定义应放在模块中：
module subs
implicit none
contains
subroutine makef(f)
real, allocatable, intent(out) :: f(:)
integer :: i
integer :: is
is=10
allocate(f(-is:is))
do i=-is,is
f(i)=i
end do
end subroutine makef
end module subs
或者，如果确实希望引用外部过程的后续实现，则接口模块可以在模块中使用，而无需声明子例程本身。在这种情况下，仍然有必要指定完整的接口：
module subs
implicit none
! An interface block to give an explicit interface to the external subroutine makef
interface
subroutine makef(f)
implicit none
real, allocatable, intent(out) :: f(:)
end subroutine makef
end interface
end module subs
在这种情况下，不要使用接口块。
本文收集自互联网，转载请注明来源。
如有侵权，请联系[email protected] 删除。
我来说两句