当我从另一个宏“调用”它时，宏不起作用，但是当我单独选择它时，它确实起作用

debugcn 发表于 Dev

丽兹·H

我下面有一个格式化宏：

Sub Colour_whole_sheet()

Dim lastRow As Long
Dim lastColumn As Long

lastRow = Range("A1").End(xlDown).Row
lastColumn = Range("A3").End(xlToRight).Column

'Colour alternate rows purple / white
For Each cell In Range(Cells(1, 1), Cells(lastRow, lastColumn))
    If cell.Row Mod 2 = 1 Then
        cell.Interior.Color = RGB(242, 230, 255)
    Else
        cell.Interior.Color = RGB(255, 255, 255)
    End If
Next cell

End Sub

当我从另一个宏调用它时，它不会运行：

Sub Run_macros()

[A bunch of other subs]
Call Colour_whole_sheet
[A bunch of other subs]

End Sub

它不会出现错误-它什么都不做。但是当我单独选择它时，从“视图”>“宏”>“视图宏”>“运行”，它可以正常工作。

你知道为什么会这样吗？

编辑：

Sub Colour_whole_sheet()

Dim ws As Worksheet
Set ws = ThisWorkbook.Worksheets("Calendar")

Dim lastRow As Long
Dim lastColumn As Long

lastRow = ws.Range("A1").End(xlDown).Row
lastColumn = ws.Range("A3").End(xlToRight).Column

'Colour alternate rows purple / white
For Each cell In ws.Range(ws.Cells(1, 1), ws.Cells(lastRow, lastColumn))
    If cell.Row Mod 2 = 1 Then
        cell.Interior.Color = RGB(242, 230, 255)
    Else
        cell.Interior.Color = RGB(255, 255, 255)
    End If
Next cell

End Sub

ᴇʜ

这里Range("A1")没有指定在哪个工作这个范围。始终指定一个工作表中所有的Range()，Cells()，Rows()和Columns()对象。

否则，您的代码很有可能在错误的工作表上运行。请注意，这适用于您的所有宏（而不仅仅是此宏）。检查是否在所有地方都指定了工作表，否则代码可能会随机工作或失败。

Dim ws As Worksheet
Set ws = ThisWorkbook.Worksheets("Sheet1") 'your sheet name here

然后调整以下几行：

lastRow = ws.Range("A1").End(xlDown).Row
lastColumn = ws.Range("A3").End(xlToRight).Column

For Each cell In ws.Range(ws.Cells(1, 1), ws.Cells(lastRow, lastColumn))

另请注意，您可以设置Excel表格的格式，以使行以彩色交替显示。

补充说明：

您使用的方法在查找最后使用的行/列时不可靠。最好反过来做。从最后一行开始，然后继续xlUp。

lastRow = ws.Cells(ws.Rows.Count, "A").End(xlUp).Row 'Last used row
lastColumn = ws.Cells(3, ws.Columns.Count).End(xlToLeft).Column 'last used column in row 3

另外，您不需要遍历所有单元格。循环遍历行即可。

Dim i As Long
For i = 1 To lastRow
    If i Mod 2 = 1 Then
        ws.Rows(i).Interior.Color = RGB(242, 230, 255)
    Else
        ws.Rows(i)..Interior.Color = RGB(255, 255, 255)
    End If
Next i

或者如果您不想为整个行着色，而只为最后使用的列着色

ws.Cells(i, lastColumn).Interior.Color

请注意，如果有很多行，单独给每行上色会大大降低速度。因此，我建议收集参考中的所有偶数/不偶数行并立即对其进行着色。

lastRow = ws.Cells(ws.Rows.Count, "A").End(xlUp).Row 'Last used row
lastColumn = ws.Cells(3, ws.Columns.Count).End(xlToLeft).Column 'last used 

Dim EvenRows As Range
Dim OddRows As Range

Dim i As Long
For i = 1 To lastRow
    If i Mod 2 = 1 Then
        If OddRows Is Nothing Then
            Set OddRows = ws.Rows(i)
        Else
            Set OddRows = Union(OddROws, ws.Rows(i))
        End If
    Else
        If EvenRows Is Nothing Then
            Set EvenRows = ws.Rows(i)
        Else
            Set EvenRows = Union(EvenRows, ws.Rows(i))
        End If
    End If
Next i

If Not OddRows Is Nothing Then OddRows.Interior.Color = RGB(242, 230, 255)
If Not EvenRows Is Nothing Then EvenRows.Interior.Color = RGB(255, 255, 255)

本文收集自互联网，转载请注明来源。

如有侵权，请联系[email protected] 删除。