Racket GUI：如何引用运行时动态创建的窗口小部件？

这取决于引用需要在哪里出现。谁需要与谁交谈？

例如，如果一个窗口小部件在同一框架中具有对另一个窗口小部件的回调，并且如果您要一起创建这两个窗口小部件，则只需命名它们，并使回调闭包引用正确的名称（即变量）即可。这是一个小示例程序：

#lang racket/gui

;; create-hello-window : -> Void
(define (create-hello-window)
  (define f (new frame% (label "Example") (width 600) (height 400)))
  (define t (new text%))
  (define ec (new editor-canvas% (parent f) (editor t)))
  (define b (new button% (parent f) (label "Say hello")
                 (callback (lambda (b ce) (say-hello t)))))
  (send f show #t)
  (void))

;; say-hello : Editor -> Void
(define (say-hello t)
  (send t set-position (send t last-position))
  (send t insert "Hello world!\n"))

;; Create two independent hello windows
(for ([i 2]) (create-hello-window))

请注意，按钮回调引用了局部变量t（编辑器）。

对于更复杂的通信，您需要将引用保存到要引用的对象的某处。这是先前程序的另一个版本，其中将窗口组织成组，每个窗口都有一个按钮，用于向组中的其他窗口写问候语。该组管理窗口及其编辑器的列表。

#lang racket/gui

;; A HelloWin is (hellowin Editor Frame)
(struct hellowin (editor frame))

;; A HelloGroup is (hellogroup String (Listof HelloWin))
(struct hellogroup (name [wins #:mutable]))

;; create-hello-window : HelloGroup -> Void
(define (create-hello-window group)
  (define f
    (new frame% (label (hellogroup-name group)) (width 600) (height 400)))
  (define t (new text%))
  (define ec (new editor-canvas% (parent f) (editor t)))
  (define hi-b
    (new button% (parent f) (label "Say hello")
         (callback (lambda (b ce) (add-to-end t "Hello world!\n")))))
  (define greet-b
    (new button% (parent f) (label "Greet others in group")
         (callback (lambda (b ce) (greet-everyone-else t group)))))
  (send f show #t)
  (set-hellogroup-wins! group (cons (hellowin t f) (hellogroup-wins group))))

;; add-to-end : Editor String -> Void
(define (add-to-end t str)
  (send t set-position (send t last-position))
  (send t insert str))

;; greet-everyone-else : Editor HelloGroup -> Void
(define (greet-everyone-else my-t group)
  (for ([h (in-list (hellogroup-wins group))])
    (define t (hellowin-editor h))
    (unless (equal? t my-t)
      (add-to-end t (format "~a, hello from another window!\n"
                            (hellogroup-name group))))))

;; Create two groups, and create windows for each group.

(define group1 (hellogroup "Group 1" null))
(for ([i 3]) (create-hello-window group1))

(define group2 (hellogroup "Group 2" null))
(for ([i 2]) (create-hello-window group2))

我的代码未使用hellowin-frame，但是您可以使用它编写一个例如关闭一个组中所有窗口的过程。

也许您不希望该组直接访问框架及其小部件。然后，您可以更改协议，以便组包含某种类型的问候语回调，或实现greetable<%>您定义的接口的对象（而不是小部件本身），等等。然后，回调（或greetable<%>对象）将具有对小部件的引用（或字段），但不会直接将其公开给组代码。同样，也许组应该是具有注册方法的对象，而不是具有可变字段的结构。