通过Excel VBA在Excel记录集中插入一行

debugcn 发表于 Dev

xnewbie

我试图在记录集的最后一行插入一些值，在这种情况下，这是一个用作我的数据库的Excel文件。我下面的代码可将文本框的值插入excel记录集的最后一行。但是，它没有在插入值的地方创建新表行。

Sub CreaterRow()
    Dim strFile As String
    Dim strConnect As String
    Dim strSQL As String
    Dim lngCount As Long
    Dim cnn As New ADODB.Connection
    Dim rst As New ADODB.Recordset
    strFile = "C:\Excel\Test.xlsx"
    strConnect = "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" & strFile & _
    ";Extended Properties=""Excel 12.0 Xml;HDR=YES"";"
    cnn.Open ConnectionString:=strConnect
    strSQL = "SELECT [ID] FROM [Sheet1$]"
    rst.Open Source:=strSQL, ActiveConnection:=cnn, CursorType:=adOpenForwardOnly, Options:=adCmdText

    With rst
        .AddNew
           .Fields("ID").Value = tbx_ID.Value 'Inserting this in the recordset did not create a new row
         .Update
    End with 

    rst.Close
    cnn.Close
End Sub

该表如何自动创建一个新行，其中将包含插入到lastrow中的值？谢谢。

蒂姆·威廉姆斯

这对我有用。您需要具有正确的光标和锁定类型。

Sub CreaterRow()
    Dim strFile As String
    Dim strConnect As String
    Dim strSQL As String
    Dim cnn As New ADODB.Connection
    Dim rst As New ADODB.Recordset

    strFile = ThisWorkbook.Path & "\Data.xlsx"

    strConnect = "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=""" & strFile & _
                """;Extended Properties=""Excel 12.0 Xml;HDR=YES"";"
    cnn.Open ConnectionString:=strConnect
    strSQL = "SELECT [ID] FROM [Sheet1$]"

    rst.Open strSQL, cnn, adOpenKeyset, adLockOptimistic

    With rst
        .AddNew
        .Fields("ID").Value = "ID00020"
        .Update
    End With

    rst.Close
    cnn.Close
End Sub

编辑：如果您要查询一个表/列表对象中的数据，那么追加记录将不会调整列表的大小以包括添加的记录。请参阅：ADO：Excel：是否可以在表名上打开记录集？

EDIT2：如果您使用命名范围而不是ListObject，则可以按名称查询它（而不是使用工作表名称），并且在插入新行时范围会调整。

本文收集自互联网，转载请注明来源。

如有侵权，请联系[email protected] 删除。