MiniZinc中的通道是什么？您能否提供一个简单的示例来说明渠道？最后，什么是逆？

两者都用于在两个阵列之间建立双向关系。

让f是与阵列index_set(f)等于1..10和值81..90。然后f可以被看作是一个映射--aka一个function--从所述一组值的1..10对所述设置值的81..90。

逆。

predicate inverse(array [int] of var int: f,
                  array [int] of var int: invf)

此约束说，如果f是映射的索引的函数i的值j，然后invf是映射的索引的函数j的值i（反之亦然）。换句话说，invf使用in中的值对数组进行索引，f并得出inf中包含的每个值的位置in f。

int_set_channel。

predicate int_set_channel(array [int] of var int: x,
                          array [int] of var set of int: y)

约束条件说，如果x是将索引映射i到给定集合的函数j，则该值i包含在索引jin中的集合中y（反之亦然）。这与逆约束完全相同，只是逆约束y是一组数组而不是值数组。

以我的经验，改变约束条件对于从一种问题视图转移到另一种问题视图很有用，以便以最自然，最有效的方式表达其他约束条件。这种类型的约束可以使用上述全局约束，也可以使用基本语言构造来表达。参见，例如，carseq.mzn。

有关更多有用信息和具体示例，请参阅docs的2.6.6.1节。

范例：

int: n;
array [1..n] of var 1..n: q; % queen is column i is in row q[i]

include "alldifferent.mzn";

constraint alldifferent(q);                       % distinct rows
constraint alldifferent([ q[i] + i | i in 1..n]); % distinct diagonals
constraint alldifferent([ q[i] - i | i in 1..n]); % upwards+downwards

include "lex_lesseq.mzn";

% Alternative Boolean model:
% Map each position i,j to a Boolean telling us whether there is a queen at i,j
array[1..n,1..n] of var bool: qb;

% Channeling constraint
constraint forall (i,j in 1..n) ( qb[i,j] <-> (q[i]=j) );

% Lexicographic symmetry breaking constraints
constraint
    lex_lesseq(array1d(qb), [ qb[j,i] | i,j in 1..n ])
/\  lex_lesseq(array1d(qb), [ qb[i,j] | i in reverse(1..n), j in 1..n ])
/\  lex_lesseq(array1d(qb), [ qb[j,i] | i in 1..n, j in reverse(1..n) ])
/\  lex_lesseq(array1d(qb), [ qb[i,j] | i in 1..n, j in reverse(1..n) ])
/\  lex_lesseq(array1d(qb), [ qb[j,i] | i in reverse(1..n), j in 1..n ])
/\  lex_lesseq(array1d(qb), [ qb[i,j] | i,j in reverse(1..n) ])
/\  lex_lesseq(array1d(qb), [ qb[j,i] | i,j in reverse(1..n) ])
;

% search
solve :: int_search(q, first_fail, indomain_min)
      satisfy;
output [ if fix(q[j]) == i then "Q" else "." endif ++
         if j == n then "\n" else "" endif | i,j in 1..n]

在这里，通道约束将模型中包含的n个皇后问题的两个视图联系起来。第一个视图q是一维的，并且告诉了女王/王后在每一列中的行位置。第二个视图qb是二维的，并告诉棋盘的哪一块被某个女王占据。第一种视图非常适合解决问题的放置部分。第二种观点对于应用对称突破约束非常有用。